[Home] Zsh logo

dot.zshenv

Zsh Wizard
Download dot.zshenv Return to Examples
  1. ########################################
  2. #
  3. # .zshenv: zsh environment settings
  4. # Written by Deborah Pickett <debbiep@csse.monash.edu.au>
  5. # with large wads taken from others.
  6. #
  7. ########################################
  9. # Since .zshenv is sourced for every invocation of zsh, it is vital that
  10. # it run quickly. Only environment variables that must be set for
  11. # a noninteractive shell are set here. If external commands must be run
  12. # here they are kept to a bare minimum and exported shell variables
  13. # remember the results to keep them from needing to be run again.
  15. ###############
  16. # zsh functions
  18. # Most functions are auto-loaded later on, but some are defined
  19. # explicitly since they're needed by the startup files and would
  20. # automatically be loaded in any case.
  22. # rationalize-path()
  23. # Later we'll need to trim down the paths that follow because the ones
  24. # given here are for all my accounts, some of which have unusual
  25. # paths in them. rationalize-path will remove
  26. # nonexistent directories from an array.
  27. rationalize-path () {
  28. # Note that this works only on arrays, not colon-delimited strings.
  29. # Not that this is a problem now that there is typeset -T.
  30. local element
  31. local build
  32. build=()
  33. # Evil quoting to survive an eval and to make sure that
  34. # this works even with variables containing IFS characters, if I'm
  35. # crazy enough to setopt shwordsplit.
  36. eval '
  37. foreach element in "$'"$1"'[@]"
  38. do
  39. if [[ -d "$element" ]]
  40. then
  41. build=("$build[@]" "$element")
  42. fi
  43. done
  44. '"$1"'=( "$build[@]" )
  45. '
  46. }
  48. # zsh-version
  49. # Return true (0) if the running version of ZSH is equal to
  50. # or more recent than the one requested. I need this because of all the
  51. # bleeding-edge zsh features I use here. :) Cache the results for
  52. # speed, if associative arrays are available.
  53. # The zsh distribution comes with the is-at-least function to do the
  54. # same job, but I'd already written this before I found that out. :)
  56. zsh-version ()
  57. {
  58. # If this result is cached . .
  59. if [[ ${+zshversioncache} -eq 1 && ${+zshversioncache[$1]} -eq 1 ]]
  60. then
  61. return $zshversioncache[$1]
  62. fi
  64. local running
  65. local wanted
  67. # Split the things to compare into two arrays.
  68. running=(${(s:.:)ZSH_VERSION})
  69. wanted=(${(s:.:)1})
  71. # Compare parts until we have an answer.
  72. while [[ $#running -gt 0 ]]
  73. do
  74. # Now compare each first part.
  75. if [[ $running[1] -lt $wanted[1] ]]
  76. then
  77. if [[ ${+zshversioncache} -eq 1 ]]
  78. then
  79. zshversioncache[$1]=1
  80. fi
  81. return 1 # Failure, want more recent than we have
  82. elif [[ $running[1] -gt $wanted[1] ]]
  83. then
  84. if [[ ${+zshversioncache} -eq 1 ]]
  85. then
  86. zshversioncache[$1]=0
  87. fi
  88. return 0 # Success, running newer version
  89. else
  90. shift running # Look at next part of version
  91. shift wanted
  92. fi
  93. done
  94. if [[ $#wanted -gt 0 ]]
  95. then
  96. if [[ ${+zshversioncache} -eq 1 ]]
  97. then
  98. zshversioncache[$1]=1
  99. fi
  100. return 1 # Failure, wanted version has an extra part and is thus later
  101. else
  102. if [[ ${+zshversioncache} -eq 1 ]]
  103. then
  104. zshversioncache[$1]=0
  105. fi
  106. return 0 # Exactly the same version
  107. fi
  108. }
  109. if zsh-version 3.1.6
  110. then
  111. # Associative arrays are available.
  112. typeset -A zshversioncache
  113. zshversioncache=( )
  114. fi
  116. ###############
  117. # Shell options
  119. # These are the options that apply to noninteractive shells.
  120. # Ones in capitals are variations from the default ZSH behaviour.
  121. setopt \
  122. no_allexport \
  123. badpattern \
  124. no_bsdecho \
  125. no_chaselinks \
  126. NO_CLOBBER \
  127. no_cshjunkieloops \
  128. no_cshjunkiequotes \
  129. no_cshnullglob \
  130. equals \
  131. no_errexit \
  132. exec \
  133. EXTENDEDGLOB \
  134. functionargzero \
  135. glob \
  136. no_globassign \
  137. GLOBDOTS \
  138. no_globsubst \
  139. hashcmds \
  140. hashdirs \
  141. no_ignorebraces \
  142. no_ksharrays \
  143. no_localoptions \
  144. no_magicequalsubst \
  145. no_markdirs \
  146. multios \
  147. nomatch \
  148. no_nullglob \
  149. NUMERICGLOBSORT \
  150. no_pathdirs \
  151. no_posixbuiltins \
  152. no_printexitvalue \
  153. PUSHDIGNOREDUPS \
  154. PUSHDMINUS \
  155. PUSHDSILENT \
  156. PUSHDTOHOME \
  157. no_rcexpandparam \
  158. no_rcquotes \
  159. rcs \
  160. no_shfileexpansion \
  161. no_shglob \
  162. no_shoptionletters \
  163. shortloops \
  164. no_shwordsplit \
  165. unset
  166. if zsh-version 3.0.6
  167. then
  168. setopt \
  169. bareglobqual \
  170. no_kshautoload \
  171. no_kshglob \
  172. no_printeightbit \
  173. no_restricted
  174. fi
  175. if zsh-version 3.1.6
  176. then
  177. setopt \
  178. no_chasedots \
  179. globalrcs \
  180. no_localtraps
  181. fi
  182. if zsh-version 3.1.8
  183. then
  184. setopt \
  185. no_cshnullcmd \
  186. NO_GLOBALEXPORT \
  187. no_octalzeroes \
  188. no_shnullcmd
  189. fi
  191. ###############
  192. # Paths for zsh
  194. # Path for cd to search; used to need to explicitly set "." for the cdmatch
  195. # function (and retained for backward compatibility).
  196. cdpath=( . )
  197. export CDPATH
  198. # Only unique entries please.
  199. typeset -U cdpath
  201. # Path to search for autoloadable functions.
  202. fpath=( $HOME/lib/zsh/func "$fpath[@]" )
  203. export FPATH
  204. # Only unique entries please.
  205. typeset -U fpath
  207. # Include function path in script path so that we can run them even
  208. # though a subshell may not know about functions.
  209. # PATH should already be exported, but in case not. . .
  210. path=(
  211. "$HOME/bin/$MACHTYPE-$OSTYPE"
  212. "$HOME/bin"
  213. /usr/local/bin
  214. /usr/local/sbin
  215. /usr/local/etc
  216. /sbin
  217. /etc
  218. /bin
  219. /usr/bin
  220. /usr/sbin
  221. /usr/ucb
  222. /usr/bsd
  223. /usr/X11/bin
  224. /usr/bin/X11
  225. /usr/local/X11/bin
  226. /usr/monash/X11/bin
  227. /usr/monash/bin
  228. /usr/monash/etc
  229. /usr/monash/gnu/bin
  230. /usr/monash/contrib/bin
  231. /usr/monash/contrib/etc
  232. /usr/monash/contrib/X11/bin
  233. /usr/local/contrib/lib/kde/bin
  234. /usr/local/tex/bin
  235. /usr/local/lib/zsh/scr
  236. /usr/monash/contrib/games
  237. /usr/local/games
  238. /usr/monash/games
  239. /usr/games
  240. "$path[@]"
  241. "$fpath[@]"
  242. )
  243. export PATH
  244. # Only unique entries please.
  245. typeset -U path
  246. # Remove entries that don't exist on this system. Just for sanity's
  247. # sake more than anything.
  248. rationalize-path path
  250. # My mail folders
  251. mailpath=(
  252. "/usr/spool/mail/$LOGNAME?You inexplicably have new mail in /usr/spool/mail/$LOGNAME"
  253. "$HOME/Mail/inbox?You have new mail in ~/Mail/inbox"
  254. "$HOME/Mail/junk?You have junk mail in ~/Mail/junk"
  255. "$HOME/Mail/uni?You have university mail in ~/Mail/uni"
  256. "$HOME/Mail/fdcmuck?You have FDCMuck mail in ~/Mail/fdcmuck"
  257. "$HOME/Mail/mermaid?You have mermaid-list mail in ~/Mail/mermaid"
  258. "$HOME/Mail/moderators?You have moderators-list mail in ~/Mail/moderators"
  259. "$HOME/Mail/picture?You have picture-list mail in ~/Mail/picture"
  260. "$HOME/Mail/life-l?You have life-list mail in ~/Mail/life-l"
  261. "$HOME/Mail/murp-l?You have murp-list mail in ~/Mail/murp-l"
  262. "$HOME/Mail/zsh?You have zsh mail in ~/Mail/zsh"
  263. "$HOME/Mail/billabong?You have billabong mail in ~/Mail/billabong"
  264. "$HOME/Mail/dryland?You have dryland mail in ~/Mail/dryland"
  265. "$HOME/Mail/fdcoz?You have FDCoz mail in ~/Mail/fdcoz"
  266. "$HOME/Mail/ldl?You have linux-dell-laptops mail in ~/Mail/ldl"
  267. )
  268. export MAILPATH
  271. ######################
  272. # functions, continued
  274. # Now that FPATH is set correctly, do autoloaded functions.
  275. # autoload all functions in $FPATH - that is, all files in
  276. # each component of the array $fpath. If there are none, feed the list
  277. # it prints into /dev/null.
  278. for paths in "$fpath[@]"
  279. do
  280. # -U switch is more recent.
  281. if zsh-version 3.1.6
  282. then
  283. autoload -U "$paths"/*(N:t) >/dev/null
  284. else
  285. autoload "$paths"/*(N:t) >/dev/null
  286. fi
  287. done
  288. unset paths
  291. #################
  292. # zsh environment
  294. # The mail folder my mail clients default to.
  295. export MAIL="$HOME/Mail/inbox"
  297. # Command to use when redirecting from/to a null command.
  298. # READNULLCMD is redefined in .zshrc for interactive shells.
  299. READNULLCMD=cat
  300. NULLCMD=cat
  302. # Size of the directory stack (pushd et al)
  303. DIRSTACKSIZE=12
  305. # Size of history list
  306. HISTSIZE=200
  308. # Unix groups: remember the original group ID. (For prompts.)
  309. if [[ ${+ORIGGID} -eq 0 ]]
  310. then
  311. export ORIGGID="$GID"
  312. fi
  315. ######################################
  316. # Other programs' environment settings
  318. # MANPATH: path for the man command to search.
  319. # Look at the manpath command's output and prepend
  320. # my own manual paths manually (ahem).
  321. if [[ ${+MANPATH} -eq 0 ]]
  322. then
  323. # Only do this if the MANPATH variable isn't already set.
  324. if whence manpath >/dev/null 2>&1
  325. then
  326. # Get the original manpath, then modify it.
  327. MANPATH="`manpath`"
  328. manpath=(
  329. "$HOME/man"
  330. "$manpath[@]"
  331. )
  332. else
  333. # This list is out of date, but it will suffice.
  334. manpath=(
  335. "$HOME/man"
  336. /usr/monash/contrib/man
  337. /usr/monash/gnu/man
  338. /usr/local/man
  339. /usr/monash/man
  340. /usr/man
  341. /usr/man/preformat
  342. /usr/X11/man
  343. /use/openwin/man
  344. /usr/monash/tex/man
  345. )
  346. rationalize-path manpath
  347. fi
  348. # And, as always, no duplicate entries are needed.
  349. typeset -U manpath
  350. export MANPATH
  351. fi
  353. # Path for info, the Anti-man(tm), to search.
  354. export INFOPATH=/usr/monash/contrib/info:/usr/local/info:/usr/monash/info:\
  355. /usr/info:/usr/emacs/info:.
  356. # Do the usual path-y things. The lowercase array one isn't used by the
  357. # info command, but it helps us to rationalize-path it.
  358. if zsh-version 3.1.6
  359. then
  360. typeset -T INFOPATH infopath
  361. rationalize-path infopath
  362. typeset -U infopath
  363. fi
  365. # Path to Qt, needed for KDE.
  366. export QTDIR=/usr/monash/contrib/lib/qt
  368. # Path for dynamic loading of libraries.
  369. export LD_LIBRARY_PATH=/usr/monash/contrib/lib:\
  370. /usr/monash/contrib/lib/qt/lib:\
  371. /usr/monash/contrib/lib/kde/lib:\
  372. "$HOME/lib/$MACHTYPE-$OSTYPE"
  373. # Do the usual path-y things. The lowercase array one isn't used by the
  374. # system, but it helps us to rationalize-path it.
  375. if zsh-version 3.1.6
  376. then
  377. typeset -T LD_LIBRARY_PATH ld_library_path
  378. rationalize-path ld_library_path
  379. typeset -U ld_library_path
  380. fi
  382. # less options.
  383. if [[ ${+LESS} -eq 0 ]]
  384. then
  385. export LESS='-deiq'
  386. # Underline non-printable characters and print them in hex
  387. # inside square brackets.
  388. export LESSBINFMT='*u[%X]'
  389. export LESSCHARSET=latin1
  390. fi
  392. # default pager
  393. if [[ ${+PAGER} -eq 0 ]]
  394. then
  395. if whence less >/dev/null 2>&1
  396. then
  397. export PAGER="`whence less`"
  398. fi
  399. fi
  401. # default editor
  402. if [[ ${+EDITOR} -eq 0 ]]
  403. then
  404. if whence vim >/dev/null 2>&1
  405. then
  406. export EDITOR="`whence vim`"
  407. fi
  408. fi
  410. # perl
  411. # Search these places for perl include files. Other paths are hopefully
  412. # configured properly already.
  413. export PERL5LIB="$HOME/lib/perl5:$HOME/lib/perl5/site_perl"
  415. # NNTP server for news
  416. export NNTPSERVER=newsserver.cc.monash.edu.au
  418. # ispell
  419. export WORDLIST="$HOME/.ispell_words"
  421. # goofey
  422. # Goofey is a chat-style program used at Monash University. It predates
  423. # ICQ and other newfangled notions by several years. I don't always use
  424. # it, since it requires a fairly reliable net connection.
  425. # If there is a file ~/.usegoofey then we'll try to use goofey on this
  426. # system. Otherwise we'll pretend it doesn't exist and skip all
  427. # related things in startup files and periodic checks.
  428. if [[ ${+USE_GOOFEY} -eq 0 && ${+NO_USE_GOOFEY} -eq 0 && -f $HOME/.usegoofey ]]
  429. then
  430. # note goofey is being used
  431. export USE_GOOFEY=1
  432. #export GOOFEYUSER=debbie
  433. else
  434. # note that it isn't being used.
  435. export NO_USE_GOOFEY=
  436. fi
  438. # Note that we're now running under a ZSH, so that future subshells can
  439. # skip some of these steps if they want. (Not that this is used at the
  440. # moment, but it's there in case I do want to do it.)
  441. export UNDERZSH=$$