[Home] Zsh logo

tele

Zsh Wizard
Download tele Return to Examples
  1. #!/bin/zsh
  2. # (c) Dominik Vogt, 12-Jul-1998, domimink.vogt@gmx.de
  3. #
  4. # tele - a (phone) database implemented as a zsh script for zsh 3.0.5. The
  5. # data is part of the script.
  6. #
  7. #
  8. # NOTE: For performance reasons you will find the documentation at the end of
  9. # this script.
  10. #
  11. #
  12. # COPYRIGHT NOTICE:
  13. #
  14. # This program is free software; you can redistribute it and/or modify
  15. # it under the terms of the GNU General Public License as published by
  16. # the Free Software Foundation; either version 2 of the License, or
  17. # (at your option) any later version.
  18. #
  19. # This program is distributed in the hope that it will be useful,
  20. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  21. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  22. # GNU General Public License for more details.
  23. #
  24. # You should have received a copy of the GNU General Public License
  25. # along with this program; if not, write to the Free Software
  26. # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
  27. #
  32. ###############################################################################
  33. # customizing section #
  34. ###############################################################################
  36. # reserved words: all, com, nl, lots of variable names in UPPERCASE
  40. ##### default options #####
  42. # Change these if you like.
  43. #DEFAULT_OPTIONS=(-s -f +o)
  44. # zsh 3.0.5 getopts bug patch
  45. DEFAULT_OPTIONS=(-s -f -O)
  49. ##### list of all defined keys #####
  51. # 'nl' must be the first entry and can be used to insert a newline character.
  52. # The value of this key is printed on the new line.
  53. KEYS=(nl tit nam fn sn nn occ cmp add po zip cit pho fax ema web hou bir ban bcn acc cus mis)
  57. ##### long form of the keys #####
  59. # The first entry is a mask for the field length. All entries should be exactly
  60. # the same length, end with a space and must be in the same order as in the
  61. # KEYS array.
  62. KEYNAMES=(\
  63. " " \
  64. "title: " \
  65. "name: " \
  66. "first name: " \
  67. "surname: " \
  68. "nickname: " \
  69. "occupation: " \
  70. "company: " \
  71. "address: " \
  72. "PO box: " \
  73. "zip: " \
  74. "city: " \
  75. "phone: " \
  76. "fax: " \
  77. "email: " \
  78. "website: " \
  79. "hours/busi.: " \
  80. "birthday: " \
  81. "bank: " \
  82. "bank code #: " \
  83. "account: " \
  84. "customer #: " \
  85. "misc.: "
  86. )
  89. ##### group definitions #####
  91. # Logical groups of keys. Groups are arrays of keynames as defined above in the
  92. # array KEYS. The 'all' group must be defined and must contain all of the keys
  93. # except 'nl' and 'com' which are reserved words. The order of the keys does
  94. # not matter, however. A '\\' prefix to the key names has a special meaning if
  95. # short output format is used (-s option):
  96. #
  97. # (substitute 'current key' for c, 'previous key' for p, 'current group' for g)
  98. #
  99. # IF c is in g
  100. # AND p ('com' and 'nl' do not count) has been printed also
  101. # AND key name of c begins with '\\'
  102. # AND p is the same as c or occurs before c in g
  103. # AND all keys between p and c begin with '\\' (in g)
  104. # THEN print current key on the same line as the last one printed.
  105. #
  106. # Note that the '\\' only occurs in the group arrays, not in the database.
  107. # The characters ',;.:' work exactly the same with the exception that they
  108. # will be printed before the space if all above conditions are met.
  109. #
  110. all=(nam tit \\fn \\sn \\nn occ cmp add po zip \\cit pho fax hou ema web bir ban bcn acc cus mis)
  111. add=(add po zip \\cit)
  112. pho=(pho fax hou)
  113. nam=(nam tit \\fn \\sn \\nn)
  114. job=(occ cmp)
  115. per=(bir)
  116. web=(ema web)
  117. acc=(ban bcn acc cus mis)
  118. # Special groups for printable output.
  119. padd=(,add \\po ,zip \\cit)
  120. ppho=(,pho ,fax ,hou)
  121. psn=(nam \\sn)
  122. pfn=(,fn ,tit)
  126. ##### list of all defined groups #####
  128. GROUPS=(all nam pho add job per web acc prt)
  132. ##### separator symbol #####
  134. # The character in the database used to separate the key names and values.
  135. # You must change it in the function 'break_stanza_lines' manually:
  136. # Replace 's:x:' with 's:y:' where x is the old separator and y the new one.
  137. KEY_SEPARATOR="|"
  141. ##### default query #####
  143. # The groups you want to see by default (e.g. name and telephone number).
  144. DEFAULT_QUERY=(nam add pho)
  148. ##### default print query #####
  150. # Special default query for the -p option. This is useful if you want to print
  151. # your the whole database (or selected keys) in a compressed format.
  152. PRINT_QUERY=(psn pfn padd ppho)
  156. ##### comment setup #####
  158. # The default strings printed before and after a comment.
  159. COM_PREFIX=""
  160. COM_SUFFIX=""
  165. ###############################################################################
  166. # do not edit below here #
  167. ###############################################################################
  169. #-------------------------
  170. # zsh configuration
  171. #-------------------------
  172. # reset options
  173. setopt LOCALOPTIONS
  174. emulate -R zsh
  175. setopt EXTENDEDGLOB
  176. setopt SHWORDSPLIT
  177. unsetopt KSHARRAYS
  178. unsetopt FUNCTIONARGZERO
  179. unsetopt ALLEXPORT
  180. # just to make sure
  181. alias echo='builtin echo'
  182. alias read='builtin read'
  184. #-------------------------
  185. # global variables
  186. #-------------------------
  187. local G_CUST=""
  188. # options
  189. local O_ARRAY=""
  190. local O_FAST=""
  191. local O_FORMAT=""
  192. local O_GSEPARATE=""
  193. local O_QTYPE=""
  194. local O_QUERY=""
  195. local G_SEP=""
  197. #-------------------------
  198. # functions
  199. #-------------------------
  201. #-------------------------
  202. # error handling functions
  203. #-------------------------
  204. function usage ()
  205. {
  206. echo "usage: ${0##*/} [ options ] [ regexp ]"
  207. if [[ -z "$1" ]] ; then
  208. echo " ${0##*/} -h for help"
  209. exit 2
  210. else
  211. echo "options:"
  212. echo " -a Select all keys in the order they appear in KEYS."
  213. echo " -c,+f Complex search. Search keys as well as record labels."
  214. echo " -C,-D string"
  215. echo " Specify the string printed before (-C) and after (-D) a comment."
  216. echo " -f,+c Fast search. Only the record labels are searched."
  217. echo " -g list|group[,group]..."
  218. echo " 'tele -g list' for a list of groups. No spaces must occur"
  219. echo " between the commas and the groups."
  220. echo " -h Print this help text."
  221. echo " -k list|key[,key]..."
  222. echo " 'tele -k list' for a list of keys. Keys with a \\-prefix (e.g."
  223. echo " \\tel are printed on the same line as the previous key if short"
  224. echo " output format (-s option) is used. No spaces are allowed in the"
  225. echo " list."
  226. echo " -l Long output style. Each key is printed on a separate line."
  227. echo " -o,+o,-O Print keys in the order of the selected groups. Otherwise (or"
  228. echo " if the +o or -O option is used) the keys are printed in the"
  229. echo " order they occur in the database."
  230. echo " -p Format output for printing. No newline is inserted between the"
  231. echo " groups. Sets the -o option. This may be changed by specifying +o"
  232. echo " anywhere after the -p option."
  233. echo " -s,+l Short output style."
  234. echo "default options: $DEFAULT_OPTIONS -g ${(j:,:)DEFAULT_QUERY}"
  235. echo "additional -p default options: -o -g ${(j:,:)PRINT_QUERY}"
  236. exit
  237. fi
  238. }
  240. check_group_all ()
  241. {
  242. if [[ ! $[ ${#all} + 1 ] = ${#KEYS} ]] ; then
  243. echo "ERROR: Group 'all' must contain all elements of 'KEYS' except 'nl'."
  244. echo "Please check your configuration at the beginning of this script."
  245. echo
  246. fi
  247. }
  249. function list_valid_keys ()
  250. {
  251. local -i I=2
  252. local -i J
  253. local -i PAD
  255. check_group_all
  256. if [[ ! ${#KEYS} = ${#KEYNAMES} ]] ; then
  257. echo "ERROR: 'KEYS' and 'KEYNAMES' have a different number of entries!"
  258. echo "Please check your configuration at the beginning of this script."
  259. echo "Possibly offending pairs of key/name:"
  260. echo
  261. J=${#KEYS}
  262. (( $J > ${#KEYNAMES} )) && J=${#KEYNAMES}
  263. I=2
  264. repeat $J ; do
  265. if [[ ! ${(L)KEYS[1]} = ${(L)KEYNAMES[1]} ]] ; then
  266. echo "$KEYS[$I] - ${KEYNAMES[$I]%: *}"
  267. fi
  268. I=$I+1
  269. done
  270. exit 3
  271. fi
  272. echo "valid keys:"
  273. echo
  274. PAD=${#KEYNAMES[1]}-1
  275. repeat $[ (${#KEYS}+1)/3 ] ; do
  276. echo " ${(r:5:: :)KEYS[$I]}${(r:$PAD:: :)${(S)KEYNAMES[$I]#:}}\c"
  277. echo " ${(r:5:: :)KEYS[$I+1]}${(r:$PAD:: :)${(S)KEYNAMES[$I+1]#:}}\c"
  278. echo " ${(r:5:: :)KEYS[$I+2]}${(r:$PAD:: :)${(S)KEYNAMES[$I+2]#:}}"
  279. I=$I+3
  280. done
  281. exit $1
  282. }
  284. function list_valid_groups ()
  285. {
  286. check_group_all
  287. echo "valid output groups:"
  288. echo " default $GROUPS[@]"
  289. echo "'default' equals to '$DEFAULT_QUERY'."
  290. exit $1
  291. }
  293. #-------------------------
  294. # break_stanza_lines
  295. #-------------------------
  296. function break_stanza_lines ()
  297. {
  298. [[ -n "$S_BROKEN" ]] && return
  299. S_BROKEN=1
  300. L_DATA=(${(s:|:)STANZA})
  301. L_NUM=$[${#L_DATA}/2]
  302. }
  304. #-------------------------
  305. # printing functions
  306. #-------------------------
  307. function print_line_long ()
  308. {
  309. local S
  311. [[ -n "$L_PANY" ]] && echo || L_PANY=1
  312. S=${KEYS[(i)$L_DATA[$LK]]}
  313. [[ $P_LAST = $S ]] && S=1 || P_LAST=$S
  314. echo "$KEYNAMES[$S]$L_DATA[$LV]\c"
  315. }
  317. function print_line_short ()
  318. {
  319. [[ -n "$L_PANY" ]] && echo "$1\c" || L_PANY=1
  320. echo "$2$L_DATA[$LV]$3\c"
  321. }
  323. function print_stanza ()
  324. {
  325. local -i I
  326. local -i J=1
  327. local -i LK
  328. local -i LV
  329. local -i NKEY
  330. local -i KEY
  331. local -i K_NUM
  332. local K_ARRAY
  333. local S
  334. local L_PRINTED
  335. local P_LAST=""
  337. break_stanza_lines
  338. # print header
  339. [[ $O_FORMAT = l ]] && echo "--> $L_DATA[1]"
  340. # print groups
  341. repeat $G_NUM ; do
  342. LK=2
  343. LV=3
  344. KEY=1
  345. S="\$$G_ARRAY[$J]"
  346. K_ARRAY=( ${(e)S}[@] )
  347. K_NUM=${#K_ARRAY}
  348. repeat $L_NUM ; do
  349. case $L_DATA[$LK] in
  350. com|nl)
  351. if [[ -n "$L_PRINTED" ]] ; then
  352. if [[ $L_PRINTED = com ]] || [[ $L_DATA[$LK] = nl ]] ; then
  353. echo
  354. [[ $O_FORMAT = l ]] && echo "$KEYNAMES[1]\c"
  355. L_PANY=""
  356. print_line_short \\n "$COM_PREFIX" "$COM_SUFFIX"
  357. L_PRINTED=com
  358. else
  359. print_line_short " " "$COM_PREFIX" "$COM_SUFFIX"
  360. L_PRINTED=com
  361. fi
  362. fi;;
  363. **)
  364. NKEY=${${K_ARRAY}[(i)[\,;.:]#$L_DATA[$LK]]}
  365. if (( $NKEY > $K_NUM )) || (( $NKEY < 1 )); then
  366. L_PRINTED=""
  367. KEY=1
  368. else
  369. if [[ $O_FORMAT = l ]] ; then
  370. print_line_long
  371. elif (( $KEY > $NKEY )) ; then
  372. if [[ $O_FORMAT = p ]] ; then
  373. case "${K_ARRAY[$NKEY][1]}" in
  374. ,|\;|.|:)
  375. print_line_short "${K_ARRAY[$NKEY][1]} ";;
  376. **) print_line_short "$G_SEP";;
  377. esac
  378. else
  379. print_line_short "$G_SEP"
  380. fi
  381. else
  382. I=$NKEY
  383. while true ; do
  384. case "${K_ARRAY[$I][1]}" in
  385. \\|,|\;|.|:) ;;
  386. **) if (( $I > $KEY )) && [[ ! $I = $NKEY ]] ; then
  387. print_line_short "$G_SEP"
  388. break
  389. fi;;
  390. esac
  391. I=$I-1
  392. if (( $I <= $KEY )) ; then
  393. case "${K_ARRAY[$NKEY][1]}" in
  394. \\) print_line_short " ";;
  395. ,|\;|.|:)
  396. print_line_short "${K_ARRAY[$NKEY][1]} ";;
  397. **) print_line_short "$G_SEP";;
  398. esac
  399. break
  400. fi
  401. done
  402. fi
  403. KEY=$NKEY
  404. L_PRINTED=1
  405. fi;;
  406. esac
  407. LK=$LK+2
  408. LV=$LV+2
  409. done
  410. J=$J+1
  411. done
  412. }
  416. #-------------------------
  417. # function complex_query
  418. #-------------------------
  419. function complex_query ()
  420. {
  421. ###
  422. [[ -n "${(MS)${(L)STANZA}#${(L)O_QUERY}}" ]]
  423. }
  427. #-------------------------
  428. # parse stanzas
  429. #-------------------------
  430. function parse_stanzas ()
  431. {
  432. local STANZA=""
  433. local S_BROKEN=""
  434. local -i G_NUM
  435. local -i G_ARNUM
  436. local -i G_DFNUM
  437. local S_PANY=""
  438. local G_ARRAY
  439. local -i L_NUM
  440. local L_DATA
  441. local L_PANY=""
  442. local K_MERGED=""
  443. local -i I
  444. local S
  445. local T_ARRAY
  446. local T_NUM
  448. if [[ -n "$O_GSEPARATE" ]] ; then
  449. G_ARRAY=($O_ARRAY)
  450. G_ARNUM=${#G_ARRAY}
  451. else
  452. G_ARRAY=(K_MERGED)
  453. G_ARNUM=1
  454. I=1
  455. repeat ${#O_ARRAY} ; do
  456. S="\$$O_ARRAY[$I]"
  457. K_MERGED=( $K_MERGED[@] ${(e)S}[@] )
  458. I=$I+1
  459. done
  460. fi
  461. G_NUM=$G_ARNUM
  463. # parse input file
  464. read 'STANZA'
  465. while [[ -n "$STANZA" ]] ; do
  466. S_BROKEN=""
  467. if [[ $O_QTYPE = f ]] || complex_query; then
  468. if [[ -z "$S_PANY" ]] ; then
  469. S_PANY=1
  470. else
  471. [[ $O_FORMAT = p ]] && echo || echo "\n"
  472. fi
  473. L_PANY=""
  474. print_stanza
  475. if [[ -z "$L_PANY" ]] ; then
  476. echo "no keys selected, printing whole record"
  477. T_ARRAY=($G_ARRAY)
  478. T_NUM=$G_NUM
  479. G_ARRAY=(all)
  480. G_NUM=1
  481. print_stanza
  482. G_ARRAY=($T_ARRAY)
  483. G_NUM=$T_NUM
  484. fi
  485. fi
  486. read 'STANZA'
  487. done
  488. [[ -n $S_PANY ]] && echo
  489. }
  492. #-------------------------
  493. # function split_stanzas
  494. #-------------------------
  495. function split_stanzas ()
  496. {
  497. sed -n "
  498. bskipline
  499. :seekhead
  500. n
  501. :skipline
  502. /^EOF$/q
  503. /^[^[:space:]].*:$/bhead
  504. bseekhead
  505. :head
  506. h
  507. /$O_FAST/bseektail
  508. bseekhead
  509. :seektail
  510. n
  511. /^[[:space:]]*$/btail
  512. s/^\([^$KEY_SEPARATOR]*\)$/\1|/g
  513. H
  514. bseektail
  515. :tail
  516. x
  517. s/\n[[:space:]]*/$KEY_SEPARATOR/g
  518. s/$KEY_SEPARATOR$KEY_SEPARATOR/$KEY_SEPARATOR $KEY_SEPARATOR/g
  519. p
  520. x
  521. bseekhead
  522. "
  523. }
  525. #-------------------------
  526. # parse options
  527. #-------------------------
  528. local -i I
  529. local S
  530. while getopts ":acC:D:fg:hk:loOps" OPT $DEFAULT_OPTIONS $*; do
  531. case $OPT in
  532. a) O_ARRAY=(all);;
  533. c|+f)
  534. O_QTYPE=c;;
  535. C) COM_PREFIX="$OPTARG";;
  536. D) COM_SUFFIX="$OPTARG";;
  537. f|+c)
  538. O_QTYPE=f;;
  539. g) [[ -z "$OPTARG" ]] && list_valid_groups 0
  540. if [[ $OPTARG = default ]] ; then
  541. O_ARRAY=( $DEFAULT_QUERY[@] )
  542. break
  543. fi
  544. I=${#O_ARRAY}+1
  545. O_ARRAY=( $O_ARRAY[@] ${(s:,:)OPTARG} )
  546. repeat $[ ${#O_ARRAY} - $I + 1 ] ; do
  547. S=${${GROUPS}[(i)${O_ARRAY[$I]}]}
  548. if (( $S < 1 )) || (( $S > ${#GROUPS} )) ; then
  549. [[ $O_ARRAY[$I] = list ]] ||
  550. echo "invalid group $O_ARRAY[$I]" >&2
  551. list_valid_groups 2
  552. fi
  553. I=$I+1
  554. done;;
  555. h) usage help;;
  556. k) [[ -z "$OPTARG" ]] && list_valid_keys 0
  557. I=${#G_CUST}+1
  558. G_CUST=( $G_CUST[@] ${(s:,:)OPTARG} )
  559. repeat $[ ${#G_CUST} - $I + 1 ] ; do
  560. S=${${KEYS}[(i)${G_CUST[$I]#+}]}
  561. if (( $S < 2 )) || (( $S > ${#KEYS} )) ; then
  562. [[ $G_CUST[$I] = list ]] ||
  563. echo "invalid key $G_CUST[$I]" >&2
  564. list_valid_keys 2
  565. fi
  566. I=$I+1
  567. done;;
  568. l|+s)
  569. G_SEP=\\n
  570. O_FORMAT=l;;
  571. o) O_GSEPARATE=1;;
  572. O|+o)
  573. O_GSEPARATE="";;
  574. p) O_FORMAT=p
  575. O_GSEPARATE=1
  576. G_SEP=" "
  577. O_ARRAY=( $PRINT_QUERY[@] );;
  578. s|+l)
  579. G_SEP=\\n
  580. O_FORMAT=s;;
  581. **) echo "illegal option '${OPTARG:-$OPT}'" >&2
  582. usage;;
  583. esac
  584. done
  586. OPTIND=$[ $OPTIND - ${#DEFAULT_OPTIONS} ]
  587. if (( $# > $OPTIND )) ; then
  588. # trailing parameters?
  589. echo "trailing parameters after pattern '$argv[$OPTIND]'" >&2
  590. usage
  591. elif [[ $O_QTYPE = f ]] ; then
  592. # fast search
  593. O_FAST="${(L)${argv[$OPTIND]}}"
  594. else
  595. # complex search
  596. O_QUERY="$argv[$OPTIND]"
  597. fi
  599. # output groups
  600. if [[ ! ${#G_CUST} = 0 ]] ; then
  601. O_ARRAY=(G_CUST)
  602. elif [[ ${#O_ARRAY} = 0 ]] ; then
  603. O_ARRAY=($DEFAULT_QUERY)
  604. fi
  606. #-------------------------
  607. # beginning of data
  608. #-------------------------
  609. # pipe the data group to the parse function (the braces are necessary here)
  610. #{ split_stanzas } <<- "EOF"
  611. { split_stanzas | parse_stanzas } <<- "EOF"
  612. fvwm (fvwm-workers):
  613. nam|fvwm
  614. web|http://fvwm.org
  615. com|fvwm home page
  616. web|ftp://fvwm.org/pub/fvwm/
  617. com|ftp site
  618. web|http://fvwm.org/fvwm-cats/
  619. com|fvwm cats page
  620. ema|fvwm@fvwm.org
  621. ema|fvwm-workers@fvwm.org
  622. ema|fvwm-announce@fvwm.org
  624. suse gmbh (suse, linux):
  625. nam|SuSE GmbH (SuSE Linux)
  626. pho|0911/7406331
  627. fax|0911/7417755
  628. com|Fax
  629. add|Schanzaeckerstr. 10
  630. zip|90443
  631. cit|Nuernberg
  632. acc|115569
  633. web|www.suse.de
  635. universitaet dortmund, unido:
  636. nam|University Dortmund (UniDo)
  637. pho|0231/7551
  638. com|Central
  639. pho|0231/7552256
  640. com|Students office (Emil-Figge Str. 66)
  641. add|Emil-Figge Str.
  642. zip|44221
  643. cit|Dortmund
  645. vogt, dominik (domivogt):
  646. fn|Dominik
  647. sn|Vogt
  648. nn|Avatar
  649. occ|fvwm hacker and zsh fanatic
  650. cmp|fvwm-workers mailing list :-)
  651. cit|Althengstett
  652. ema|dominik.vogt@gmx.de
  653. web|http://fvwm.org
  655. EOF
  656. # The last line before the EOF *must* be empty or the last stanza
  657. # will not be used!!
  663. # DOCUMENTATION
  664. #
  665. #
  666. # Note:
  667. #
  668. # You can find detailed examples at the end of this documentation.
  669. #
  670. # OVERVIEW:
  671. #
  672. # This script implements a database based solely on zsh functionality. The
  673. # only external program used is sed (for performace reasons only). The
  674. # purpose of this script is to provide a small, fast, extendable and portable
  675. # database. It began as a simple phone and address database, but I added new
  676. # types of datasets as I needed them. Today I use it for all the data and
  677. # numbers that were strewn over piles of paper, booklets and files. You can
  678. # run this script on any platform that provides a bug free sed command.
  679. # Should this not work you can still 'vi =tele' this file and look up the
  680. # needed record yourself.
  681. #
  682. # The data is stored in records that are described by stanzas of a certain
  683. # format. A stanza consits of a title and one or more key/value pairs. By
  684. # default a query is limited to the title, but more complex (but slower)
  685. # queries that look at the complete record can be used too.
  686. #
  687. # The keys are abbreviations for the interesting data in the record like 'fn'
  688. # (first name), 'sn' (surname), 'pho' (phone number) and so on. The keys are
  689. # assembled in groups for convenience reasons. The 'add' (address) group
  690. # consists of the keys 'add' (address), 'po' (PO box), 'zip' and 'cit' (city)
  691. # for example. The default query prints the contents of the 'nam' (name),
  692. # 'pho' (phone) and 'add' groups.
  693. #
  694. # In general you have to specify which records and which keys from these
  695. # records you want to see.
  696. #
  697. #
  698. # ADDING RECORDS:
  699. #
  700. # All records are entered in stanzas at the end of this script. The format of
  701. # a record (stanza) is this:
  702. #
  703. # TITLE:
  704. # <tab>KEY|CONTENTS
  705. # <tab>KEY|CONTENTS
  706. # ...
  707. # <empty line>
  708. #
  709. # The TITLE must begin at the start of a line and end with a colon (':').
  710. # The following lines must begin with a tab followed by the KEY, a '|' and
  711. # the data itself. Multiple keys of the same type can be used in one stanza.
  712. # The last line of the stanza *must* be empty to separate if from the
  713. # following stanzas. For example:
  714. #
  715. # vogt, dominik (domivogt):
  716. # fn|Dominik
  717. # sn|Vogt
  718. # nn|Avatar
  719. # cit|Althengstett
  720. #
  721. # vogt, melanie (melle):
  722. # ...
  723. #
  724. # Note: although you can put anything you like in the title, remember that
  725. # most queries look at the titles only. So be sure to put all the information
  726. # you prefer into the title. Personally I put the first name, surname,
  727. # nickname and other keywords like 'doctor' there. Using lower case letters
  728. # only in the title makes querying easier.
  729. #
  730. # Note: Do not use the separator character ('|'). If you need it you can
  731. # configure a different character (see customizing section).
  732. #
  733. # The preconfigured keys are:
  734. #
  735. # tit (title)
  736. # nam (name)
  737. # fn (first name)
  738. # sn (surname)
  739. # nn (nickname)
  740. # occ (occupation)
  741. # cmp (company)
  742. # add (address)
  743. # po (PO box)
  744. # zip (zip)
  745. # cit (city)
  746. # pho (phone)
  747. # fax (fax)
  748. # ema (email)
  749. # web (website)
  750. # hou (hours of business)
  751. # bir (birthday)
  752. # ban (bank)
  753. # bcn (bank code number)
  754. # acc (account)
  755. # cus (customer number)
  756. # mis (miscellaneous)
  757. #
  758. # and two special keys:
  759. #
  760. # nl (newline)
  761. # com (comment)
  762. #
  763. # All comments and newlines are printed whenever the previous line of the
  764. # stanza is printed. E.g.
  765. #
  766. # pho|01234/567890
  767. # com|home
  768. # nl|
  769. # pho|09876/54-3210
  770. # com|office
  771. #
  772. # would be printed as
  773. #
  774. # Phone: 01234/567890 home
  775. #
  776. # Phone: 09876/54-3210 office
  777. #
  778. #
  779. # SYNOPSIS:
  780. #
  781. # tele [ options ] [ search word ]
  782. #
  783. # The search word determines which records in the database are selected
  784. # (and hence printed out). If no search word is gicen, all records are
  785. # selected. When using the fast search option (-f or +c), tele looks for
  786. # matches in the label of each record (the first line). The search word
  787. # is a regular expression as implemented by your version of sed then. With
  788. # a complex search (-c or +f option) the contents of all keys are searched.
  789. # For performance reasons only simple strings are supported (to be honest,
  790. # now that I write this manual I don't understand my script any more. If
  791. # you want to implement regexp complex search you will have to rewrite the
  792. # 'complex_search' function in this script. If you do so, please send me
  793. # your version of the function.) In either case the match is case
  794. # insensitive.
  795. #
  796. # output options:
  797. #
  798. # -a
  799. # Select all keys in the order they appear in KEYS.
  800. #
  801. # -C string
  802. # -D string
  803. # Specify the string printed before (-C) and after (-D) a comment.
  804. #
  805. # -g list|group[,group]...
  806. # Use 'tele -g list' for a list of defined groups (see customizing
  807. # section). If a comma separated list of groups is given, all
  808. # information in the selected records in one of the given groups
  809. # is printed. No spaces must occur between the commas and the groups.
  810. #
  811. # -k list|key[,key]...
  812. #
  813. # Use 'tele -k list' for a list of defined keys (see customizing
  814. # section). If a comma separated list of keys is given, the given
  815. # keys in the selected records are printed. No spaces must occur
  816. # between the commas and the keys.
  817. #
  818. # -l
  819. # Long output style. Each key is printed on a separate line with a
  820. # label.
  821. #
  822. # +l
  823. # Same as -s. Turns off the -l option.
  824. #
  825. # -o
  826. # Print keys in the order of the selected groups.
  827. #
  828. # +o
  829. # Print keys in the order they occur in the database.
  830. #
  831. # -O Same as +o.
  832. #
  833. # -p
  834. # Format output for compact printing. No newline is inserted between the
  835. # groups. Sets the -o option. This may be changed by specifying +o
  836. # anywhere after the -p option.
  837. #
  838. # -s
  839. # Short output style. No labels are printed, information such as names
  840. # and titles are printed on a single line.
  841. #
  842. # +s
  843. # Same as -l. Turns off the +s option.
  844. #
  845. # record selection options:
  846. #
  847. # -c
  848. # Complex search. Search keys as well as record labels.
  849. #
  850. # +c
  851. # Same as -f. Turns off the -c option.
  852. #
  853. # -f
  854. # Fast search. Search only the record labels for matvches.
  855. #
  856. # +f
  857. # Same as -c. Turns off the -f option.
  858. #
  859. # other options:
  860. #
  861. # -h
  862. # Print a help text.
  863. #
  864. # default options:
  865. #
  866. # -s -f -O -g nam,add,pho
  867. #
  868. # default options when using the -p option:
  869. #
  870. # -s -f -o -g psn,pfn,padd,ppho
  871. #
  872. #
  873. # CUSTOMIZING:
  874. #
  875. # Please see the customizing section at the beginning of the script. I hope
  876. # the comments there are detailed enough to allow you to tinker with the
  877. # details of my script.
  878. #
  879. #
  880. # EXAMPLES:
  881. #
  882. # I have prepared a few records to demonstrate the usage of this script.
  883. #
  884. #
  885. # Simple query with default options (short output):
  886. #
  887. # # tele suse
  888. # S.u.S.E. GmbH (SuSE Linux)
  889. # 0911/7406331
  890. # 0911/7417755 Fax
  891. # Schanzaeckerstr. 10
  892. # 90443 Nuernberg
  893. #
  894. #
  895. # Long output format:
  896. #
  897. # # tele -l suse
  898. # --> suse gmbh (suse, linux):
  899. # name: SuSE GmbH (SuSE Linux)
  900. # phone: 0911/7406331
  901. # fax: 0911/7417755 Fax
  902. # address: Schanzaeckerstr. 10
  903. # zip: 90443
  904. # city: Nuernberg
  905. #
  906. #
  907. # Selecting a single key:
  908. #
  909. # # tele -l -k occ domi
  910. # --> vogt, dominik (domivogt):
  911. # occupation: fvwm hacker and zsh fanatic
  912. #
  913. #
  914. # Fast versus complex search:
  915. #
  916. # # tele -lf avatar
  917. # --> fvwm (fvwm-workers):
  918. # name: fvwm
  919. #
  920. # # tele -lc fvwm
  921. # --> fvwm (fvwm-workers):
  922. # name: fvwm
  923. #
  924. # --> vogt, dominik (domivogt):
  925. # first name: Dominik
  926. # surname: Vogt
  927. # nickname: Avatar
  928. # city: Althengstett
  929. #
  930. #
  931. # Viewing the complete record
  932. #
  933. # # tele -a domi
  934. # Dominik Vogt Avatar
  935. # fvwm hacker and zsh fanatic
  936. # fvwm-workers mailing list :-)
  937. # Althengstett
  938. # dominik.vogt@gmx.de
  939. # http://fvwm.org
  940. #
  941. #
  942. # Customized comment delimiters:
  943. #
  944. # # tele -C "<<" -D ">>" -a fvwm
  945. # fvwm
  946. # http://fvwm.org <<fvwm home page>>
  947. # ftp://fvwm.org/pub/fvwm/ <<ftp site>>
  948. # http://fvwm.org/fvwm-cats/ <<fvwm cats page>>
  949. # fvwm@fvwm.org
  950. # fvwm-workers@fvwm.org
  951. # fvwm-announce@fvwm.org
  952. #
  953. #
  954. # Ordering keys in output:
  955. #
  956. # # tele -o -g add,nam suse
  957. # Schanzaeckerstr. 10
  958. # 90443 Nuernberg
  959. # SuSE GmbH (SuSE Linux)
  960. #
  961. # # tele -O -g add,nam suse
  962. # SuSE GmbH (SuSE Linux)
  963. # Schanzaeckerstr. 10
  964. # 90443 Nuernberg
  965. #
  966. #
  967. # BUGS:
  968. #
  969. # Due to a bug in the getopts builtin in zsh 3.0.5 all command line options
  970. # with a leading '+' do not work. Use the corresponding options with
  971. # beginning with '-' instead.
  972. #
  973. # Some implementations of sed don't understand \n to denote a newline in
  974. # search patterns. If you have such a version of sed the script will not
  975. # print the records you want. In this case you have to replace this line of
  976. # the embedded sed script:
  977. #
  978. # s/\n[[:space:]]*/$KEY_SEPARATOR/g
  979. #
  980. # with these two:
  981. #
  982. # s/\
  983. #[[:space:]]*/$KEY_SEPARATOR/g
  984. #
  985. # I.e. insert a \ followed by a line break instead of the \n.