[Home] Zsh logo

tailsh

Zsh Wizard
Download tailsh Return to Examples
  1. #!/bin/zsh
  2. #
  3. # tailsh - runs a file through sh, ignoring lines before
  4. # the line reading "#!". Useful if someone mails you a shell
  5. # script and you're too lazy to save to a temp file, strip the stuff
  6. # from the top, chmod it to be executable, run the script and
  7. # delete the temporary file.
  8. #
  9. # It works on things other than /bin/sh. What it actually
  10. # does is pass the lines following the first #! line into the
  11. # command named on the #! line.
  12. #
  13. # Usage:
  14. # tailsh [-p path] [-c command] [-o options] [file . . .]
  15. #
  16. # Where
  17. # -p path means tailsh will perform a cd to path before running
  18. # each file. Files given as parameters to tailsh
  19. # are intelligently renamed so that they can still be found
  20. # if relative paths were given.
  21. # -c command overrides the command to run the script through.
  22. # useful if the script was written by someone who puts
  23. # /bin/sh in a different place. This switch overrides
  24. # *all* files given on the line, even though each file
  25. # may have a different command in its #! line
  26. # -o options supplies options to the file, making it believe
  27. # they were supplied as command-line options.
  28. # This really only works with scripts that invoke
  29. # a shell of some sort with any reliability. All it
  30. # does is put them after the temp file name it creates.
  31. # Importantly, it works with sh and zsh.
  32. # file is the name of a file to be sourced in this fashion.
  33. # If no files are supplied, tailsh will run the entire
  34. # standard input as if it were a single file. tailsh is
  35. # more efficient in stdin mode.
  36. #
  37. # Examples:
  38. # tailsh -o '-c' part1of3.shar part2of3.shar part3of3.shar
  39. # Run each of the three shar files you were just mailed.
  40. # Depending on what your version of shar is like it should
  41. # completely decode the whole thing.
  42. #
  43. # Written by Deborah Pickett <debbiep@csse.monash.edu.au>
  44. #
  45. # To do: Maybe find a way of doing the stdin style on a filename
  46. # provided. On the other hand, it's more general if you can supply
  47. # a filename rather than rely on stdin. The present compromise
  48. # is probably best. Redirect from stdin if you can, otherwise
  49. # name a file. The down side is that it doesn't appear to work for
  50. # substituted files, i.e., <(some command). Use =(some command)
  51. # instead.
  52. # Also need a better mechanism for passing perceived parameters;
  53. # the -o switch isn't very portable.
  55. # local variables
  56. local neg sws file line linenum opt newpath overridecmd passopts\
  57. usage="Usage: $0:t [-p path] [-c command] [-o options] file . . ." \
  58. excl=!
  60. # fetch options
  61. while getopts :p:c:o: opt
  62. do
  63. case $opt in
  64. 'p') newpath=$OPTARG ;;
  65. 'c') overridecmd=$OPTARG ;;
  66. 'o') passopts=$OPTARG ;;
  67. ':') echo $usage >&2 ; return 1 ;;
  68. '?') echo $usage >&2 ; return 1 ;;
  69. esac
  70. done
  72. # put options behind us
  73. shift $[ $OPTIND - 1 ]
  75. # extendedglob and shwordsplit need to be set thusly
  76. [[ -o extendedglob ]] || neg=1
  77. setopt extendedglob
  78. [[ -o shwordsplit ]] && sws=1
  79. unsetopt shwordsplit
  81. # tailsh proper
  82. if [[ $# -ne 0 ]]
  83. then
  84. # files specified - read them in one at a time
  85. for file
  86. do
  87. # if file doesn't start with "/" it was relative and needs $PWD
  88. # prepended so that it still can be found when -c was used.
  89. if [[ "$newpath" != "" && "$file[1]" != "/" ]]
  90. then
  91. file=$PWD/$file
  92. fi
  93. # check for existence of file
  94. if [[ ! -r $file ]]
  95. then
  96. echo "${0:t}: $file: no such file" >&2
  97. continue
  98. fi
  99. # find first line containing a #!
  100. # This sed script outputs the line number followed by the command
  101. # itself. It exits after the first #! is found; this avoids
  102. # duplicates. It's simpler to extract it from an array, thus
  103. # the surrounding brackets.
  104. # (This looks hideous and there's good reason.
  105. # Owing to what I think is a misfeature of zsh's handling of
  106. # ! characters, I can't quote any as "\!" or '\!' because it
  107. # is treated as ! in a zsh function if nobanghist is off,
  108. # \! in a zsh function if nobanghist is on,
  109. # and \! in a zsh script regardless of the settings of nobanghist.
  110. # I solve this by setting a shell variable to contain the
  111. # exclamation mark. [This has probably been solved in zsh version 3,
  112. # but I haven't changed it because this way we get backwards
  113. # compatibility.] )
  114. line=($(sed -n '/#'$excl'/{=;s/#'$excl' *//p;q;}' < $file))
  115. if [[ "$line" != "" ]]
  116. then
  117. # there was a #! - find its line number.
  118. linenum=${line[1]}
  119. # cd to the path given by -c if it was specified
  120. if [[ "$newpath" != "" ]]
  121. then
  122. cd $newpath
  123. fi
  124. # run the command. "eval" is used in case the command
  125. # was somthing like "cat >foo" and the shell needs to
  126. # see it. It also helps sidestep that annoying ! feature.
  127. eval ${overridecmd:-${line[2,-1]}} \
  128. =(tail +$[$linenum+1] $file) ${=passopts}
  129. # cd back to the old path to make it look like nothing happened.
  130. if [[ "$newpath" != "" ]]
  131. then
  132. cd $OLDPWD
  133. fi
  134. else
  135. # file didn't have a #! - ignore it.
  136. echo "${0:t}: $file: no #"\!" line" >&2
  137. fi
  138. done
  139. else
  140. # no files named - must be wanting stdin mode.
  141. linenum=0;
  142. # keep reading lines till something happens.
  143. while read -r -u0 line
  144. do
  145. if [[ $line[1,2] = \#\! ]]
  146. then
  147. # found a #! - flag the fact we have found it.
  148. linenum=1
  149. if [[ "$newpath" != "" ]]
  150. then
  151. cd $newpath
  152. fi
  153. # duplicate our stdin and give it to the command.
  154. # If no command is supplied (i.e. the line was #! and nothing
  155. # else), it's a null command, which defaults to calling
  156. # cat(1) implicitly. Just an interesting side-effect.
  157. eval ${overridecmd:-${line##\#\! #}} "<&0" "${=passopts}"
  158. if [[ "$newpath" != "" ]]
  159. then
  160. cd $OLDPWD
  161. fi
  162. # and break out of the loop.
  163. break
  164. fi
  165. done
  166. if [[ $linenum = 0 ]]
  167. then
  168. # No #! line - output warning message.
  169. echo "${0:t}: stdin: no #"\!" line" >&2
  170. fi
  171. fi
  173. # restore option settings
  174. [[ "$neg" = 1 ]] && unsetopt extendedglob
  175. [[ "$sws" = 1 ]] && setopt shwordsplit