[Home] Zsh logo

two_line_prompt

Zsh Wizard
Download two_line_prompt Return to Examples
  1. # The following function generates a two-line PS1 prompt. It uses two new
  2. # array variables, abovePS1 and aboveRPS1, either of which may be empty or
  3. # unset. Each of these is a series of prompt segments that should appear,
  4. # obviously, above the regular PS1 and RPS1 prompts. (I generally prefer to
  5. # put the extra info in the xterm title bar, but when not using an xterm
  6. # this can be handy.)
  7. #
  8. # To use the two-line prompt:
  9. #
  10. # function precmd() {
  11. # two_line_prompt
  12. # }
  13. abovePS1=(%m %n %~)
  14. aboveRPS1=(%W %@ tty%l) # Remember, display is reversed to tty%l %@ %W.
  16. realPS1=$PS1 # Save the original PS1 for later use
  18. two_line_prompt() {
  19. local fakePS1="" fakeRPS1="" p P
  21. for p in $abovePS1
  22. do
  23. # Compute the width of each abovePS1 segment. If the total
  24. # width so far is wider than the screen, omit the segment.
  25. P=$(print -nP $p)
  26. if [[ $[$#fakePS1+$#P] -lt $[$COLUMNS-1] ]]
  27. then fakePS1="${fakePS1:+$fakePS1 }$P"
  28. fi
  29. done
  31. for p in $aboveRPS1
  32. do
  33. # Add in the width of each aboveRPS1 segment. If the total
  34. # width so far is wider than the screen, omit the segment.
  35. P=$(print -nP $p)
  36. if [[ $[$#fakePS1+$#fakeRPS1+$#P] -lt $COLUMNS-1 ]]
  37. then fakeRPS1="$P${fakeRPS1:+ $fakeRPS1}"
  38. fi
  39. done
  41. if [[ $[$#fakePS1+$#fakeRPS1] -gt 0 ]]
  42. then
  43. # Reset fakeRPS1 to use right-justified display (typeset -R) at
  44. # the correct width to push it to the right edge of the screen.
  45. local -R $[$COLUMNS-$#fakePS1-1] fakeRPS1="$fakeRPS1"
  47. # Prefix PS1 with the first line of the two-line prompt.
  48. PS1="$fakePS1$fakeRPS1
  49. $realPS1"
  50. else PS1=$realPS1
  51. fi
  52. }