[Home] Zsh logo

multicomp

Zsh Wizard
Download multicomp Return to Examples
  1. # multicomp() {
  2. # Completes all manner of files given prefixes for each path segment.
  3. # e.g. s/z/s -> src/zsh-2.4/src
  4. #
  5. # Usage: e.g.
  6. # compctl -D -f + -U -K multicomp
  7. #
  8. # Note that exactly matched directories are not expanded, e.g.
  9. # s/zsh-2.4/s<TAB> will not expand to src/zsh-2.4old/src.
  10. # Will expand glob patterns already in the word, but use complete-word,
  11. # not TAB (expand-or-complete), or you will get ordinary glob expansion.
  12. # Requires the -U option to compctl.
  13. # Menucompletion is highly recommended for ambiguous matches.
  14. # Liable to screw up escaped metacharacters royally.
  15. # $fignore is not used: feel free to add your own bit.
  17. local pref head sofar origtop newtop globdir="(-/)" wild
  18. setopt localoptions nullglob rcexpandparam globdots
  19. unsetopt markdirs globsubst shwordsplit
  21. pref="${1}$2"
  22. # Hack to allow programmable completion to select multicomp after a :
  23. # (e.g.
  24. # compctl -D -f -x 's[:]' -U -K multicomp
  25. # )
  26. pref="${pref#:}"
  28. sofar=('')
  29. reply=('')
  31. if [[ "$pref" = \~* ]]; then
  32. # If the string started with ~, save the head and what it will become.
  33. origtop="${pref%%/*}"
  34. newtop=${~origtop}
  35. # Save the expansion as the bit matched already
  36. sofar=($newtop)
  37. pref="${pref#$origtop}"
  38. fi
  40. while [[ -n "$pref" ]]; do
  41. [[ "$pref" = /* ]] && sofar=(${sofar}/) && pref="${pref#/}"
  42. head="${pref%%/*}"
  43. pref="${pref#$head}"
  44. if [[ -n "$pref" && -z $sofar[2] && -d "${sofar}$head" ]]; then
  45. # Exactly matched directory: don't try to glob
  46. reply=("${sofar}$head")
  47. else
  48. [[ -z "$pref" ]] && globdir=
  49. # if path segment contains wildcards, don't add another.
  50. if [[ "$head" = *[\*\?]* ]]; then
  51. wild=
  52. else
  53. wild='*'
  54. fi
  55. reply=(${sofar}"${head}${wild}${globdir}")
  56. reply=(${~reply})
  57. fi
  59. [[ -z $reply[1] ]] && reply=() && break
  60. [[ -n $pref ]] && sofar=($reply)
  61. done
  63. # Restore ~'s in front if there were any.
  64. # There had better not be anything funny in $newtop.
  65. [[ -n "$origtop" ]] && reply=("$origtop"${reply#$newtop})
  67. # }